Inverse Colour Dodge

--if a = 255 then
--  result := 255
--else begin
--  c := (b SHL 8) DIV (255-a);
--  if c > 255 then result := 255 else result := c;
--end;
-- ******* inverse color dodge mode *************
on inverseColorDodgeBlendMode (image1, image2)
  theWidth = image1.width - 1
  theHeight = image1.height - 1
  theImage = image(theWidth + 1, theHeight + 1, 32)
  theMultiplier = 255.0
 
  repeat with x = 0 to theWidth
    repeat with y = 0 to theHeight
      theColour1 = image1.getPixel(point(x,y))
      theColour2 = image2.getPixel(point(x,y))
      theNewColour = color(0,0,0)
      if theColour1.red = 255 then
        theNewColour.red = 255
      else
        theNewColour.red = min((theColour2.red * theMultiplier) / (255 - theColour1.red), 255)
      end if
      if theColour1.green = 255 then
        theNewColour.green = 255
      else
        theNewColour.green = min((theColour2.green * theMultiplier) / (255 - theColour1.green), 255)
      end if
      if theColour1.blue = 255 then
        theNewColour.blue = 255
      else
        theNewColour.blue = min((theColour2.blue * theMultiplier) / (255 - theColour1.blue), 255)
      end if
      theImage.setPixel(point(x, y), theNewColour)
    end repeat
  end repeat
  return theImage
end